Nand2Tetris — 第5章

// Memory
//入力: in[16], load, address[15]
//出力: out[16]
//アクション：
// address[0..13]  : RAM16K
//address[14]=0 : RAM領域
// address[14]=1, address[13]=0 : Screen
// address[14]=1, address[13]=1 : Keyboard
//Keyboardは読み取り専用なので、loadを接続しない

CHIP Memory {
    IN in[16], load, address[15];
    OUT out[16];

    PARTS:
    DMux4Way(in=load, sel=address[13..14],
             a=loadRamA, b=loadRamB, c=loadScreen, d=ignore);

    Or(a=loadRamA, b=loadRamB, out=loadRam);

    RAM16K(in=in, load=loadRam, address=address[0..13], out=ramOut);
    Screen(in=in, load=loadScreen, address=address[0..12], out=screenOut);
    Keyboard(out=keyboardOut);

    Mux4Way16(a=ramOut, b=ramOut, c=screenOut, d=keyboardOut,
              sel=address[13..14], out=out);
}

// CPU
//入力: inM[16], instruction[16], reset
//出力：
//outM[16] : メモリに書き込む値
//writeM：Mに値を書き込むかどうか
//addressM：アクセスするメモリアドレス（Aレジスタ）
//pc: 次の命令アドレス
//アクション：
//A-instructionの場合、Aレジスタにinstruction値を格納します
//C-instructionの場合、comp、dest、jumpフィールドに基づいてALUとレジスタを制御します。

CHIP CPU {
    IN  inM[16], instruction[16], reset;
    OUT outM[16], writeM, addressM[15], pc[15];

    PARTS:
    //命令の種類判別
    Not(in=instruction[15], out=isA);
    And(a=instruction[15], b=true, out=isC);

    //Aレジスタ入力の選択
    Mux16(a=instruction, b=aluOut, sel=isC, out=aInput);
    And(a=isC, b=instruction[5], out=loadAFromC);
    Or(a=isA, b=loadAFromC, out=loadA);
    ARegister(in=aInput, load=loadA, out=aOut, out[0..14]=addressM);

    //Dレジスタ
    And(a=isC, b=instruction[4], out=loadD);
    DRegister(in=aluOut, load=loadD, out=dOut);

    //ALUのy入力選択：aビットが0の場合A、1の場合M
    Mux16(a=aOut, b=inM, sel=instruction[12], out=aluY);

    ALU(x=dOut, y=aluY,
        zx=instruction[11],
        nx=instruction[10],
        zy=instruction[9],
        ny=instruction[8],
        f=instruction[7],
        no=instruction[6],
        out=aluOut,
        out=outM,
        zr=zr,
        ng=ng);

    //destのMビット
    And(a=isC, b=instruction[3], out=writeM);

    //jump 計算
    Not(in=zr, out=notZr);
    Not(in=ng, out=notNg);
    And(a=notZr, b=notNg, out=positive);

    And(a=instruction[0], b=positive, out=jgt);
    And(a=instruction[1], b=zr, out=jeq);
    And(a=instruction[2], b=ng, out=jlt);

    Or(a=jgt, b=jeq, out=jump1);
    Or(a=jump1, b=jlt, out=jumpCond);
    And(a=isC, b=jumpCond, out=pcLoad);

    PC(in=aOut, load=pcLoad, inc=true, reset=reset, out[0..14]=pc);
}

// Computer
//入力：リセット
//出力：なし
//アクション：
//ROM32Kからinstructionを読み、
//CPUがメモリを読み書きし、
//PCが次の命令アドレスを決定する

CHIP Computer {
    IN reset;

    PARTS:
    ROM32K(address=pc, out=instruction);
    CPU(inM=memOut, instruction=instruction, reset=reset,
        outM=outM, writeM=writeM, addressM=addressM, pc=pc);
    Memory(in=outM, load=writeM, address=addressM, out=memOut);
}