Nand2Tetris — Capítulo 5

// Memory
//Entrada: en[16], carga, dirección[15]
//salida: fuera[16]
//movimiento:
// address[0..13]  : RAM16K
//dirección[14]=0: área de RAM
// address[14]=1, address[13]=0 : Screen
// address[14]=1, address[13]=1 : Keyboard
//El teclado es de sólo lectura, por lo que no hay carga adjunta.

CHIP Memory {
    IN in[16], load, address[15];
    OUT out[16];

    PARTS:
    DMux4Way(in=load, sel=address[13..14],
             a=loadRamA, b=loadRamB, c=loadScreen, d=ignore);

    Or(a=loadRamA, b=loadRamB, out=loadRam);

    RAM16K(in=in, load=loadRam, address=address[0..13], out=ramOut);
    Screen(in=in, load=loadScreen, address=address[0..12], out=screenOut);
    Keyboard(out=keyboardOut);

    Mux4Way16(a=ramOut, b=ramOut, c=screenOut, d=keyboardOut,
              sel=address[13..14], out=out);
}

// CPU
//Entrada: inM[16], instrucción[16], restablecer
//salida de potencia:
//outM[16]: Valor a escribir en memoria
//writeM: si se debe escribir el valor en M
//direcciónM: Dirección de memoria a la que acceder (registro A)
//pc: siguiente dirección de instrucción
//movimiento:
//Si es una instrucción A, el valor de la instrucción se almacena en el registro A.
//Si se trata de una instrucción C, la ALU y los registros se controlan según los campos comp, dest y jump.

CHIP CPU {
    IN  inM[16], instruction[16], reset;
    OUT outM[16], writeM, addressM[15], pc[15];

    PARTS:
    //Determinación del tipo de comando
    Not(in=instruction[15], out=isA);
    And(a=instruction[15], b=true, out=isC);

    //Una selección de entrada de registro
    Mux16(a=instruction, b=aluOut, sel=isC, out=aInput);
    And(a=isC, b=instruction[5], out=loadAFromC);
    Or(a=isA, b=loadAFromC, out=loadA);
    ARegister(in=aInput, load=loadA, out=aOut, out[0..14]=addressM);

    //registro D
    And(a=isC, b=instruction[4], out=loadD);
    DRegister(in=aluOut, load=loadD, out=dOut);

    //Selección de la entrada y de ALU: A si un bit es 0, M si un bit es 1
    Mux16(a=aOut, b=inM, sel=instruction[12], out=aluY);

    ALU(x=dOut, y=aluY,
        zx=instruction[11],
        nx=instruction[10],
        zy=instruction[9],
        ny=instruction[8],
        f=instruction[7],
        no=instruction[6],
        out=aluOut,
        out=outM,
        zr=zr,
        ng=ng);

    //M poco de destino
    And(a=isC, b=instruction[3], out=writeM);

    //cálculo de salto
    Not(in=zr, out=notZr);
    Not(in=ng, out=notNg);
    And(a=notZr, b=notNg, out=positive);

    And(a=instruction[0], b=positive, out=jgt);
    And(a=instruction[1], b=zr, out=jeq);
    And(a=instruction[2], b=ng, out=jlt);

    Or(a=jgt, b=jeq, out=jump1);
    Or(a=jump1, b=jlt, out=jumpCond);
    And(a=isC, b=jumpCond, out=pcLoad);

    PC(in=aOut, load=pcLoad, inc=true, reset=reset, out[0..14]=pc);
}

// Computer
//Entrada: restablecer
//Salida: Ninguna
//movimiento:
//Lea las instrucciones de ROM32K,
//La CPU lee y escribe memoria,
//La PC determina la siguiente dirección de instrucción

CHIP Computer {
    IN reset;

    PARTS:
    ROM32K(address=pc, out=instruction);
    CPU(inM=memOut, instruction=instruction, reset=reset,
        outM=outM, writeM=writeM, addressM=addressM, pc=pc);
    Memory(in=outM, load=writeM, address=addressM, out=memOut);
}