Nand2Tetris — 5장

// Memory
// 입력: in[16], load, address[15]
// 출력: out[16]
// 동작:
// address[0..13]  : RAM16K
// address[14]=0   : RAM 영역
// address[14]=1, address[13]=0 : Screen
// address[14]=1, address[13]=1 : Keyboard
// Keyboard는 읽기 전용이므로 load를 연결하지 않음

CHIP Memory {
    IN in[16], load, address[15];
    OUT out[16];

    PARTS:
    DMux4Way(in=load, sel=address[13..14],
             a=loadRamA, b=loadRamB, c=loadScreen, d=ignore);

    Or(a=loadRamA, b=loadRamB, out=loadRam);

    RAM16K(in=in, load=loadRam, address=address[0..13], out=ramOut);
    Screen(in=in, load=loadScreen, address=address[0..12], out=screenOut);
    Keyboard(out=keyboardOut);

    Mux4Way16(a=ramOut, b=ramOut, c=screenOut, d=keyboardOut,
              sel=address[13..14], out=out);
}

// CPU
// 입력: inM[16], instruction[16], reset
// 출력:
// outM[16]   : 메모리에 쓸 값
// writeM     : M에 값을 쓸지 여부
// addressM   : 접근할 메모리 주소 (A 레지스터)
// pc         : 다음 명령어 주소
// 동작:
// A-instruction이면 A 레지스터에 instruction 값을 저장함
// C-instruction이면 comp, dest, jump 필드에 따라 ALU와 레지스터를 제어함

CHIP CPU {
    IN  inM[16], instruction[16], reset;
    OUT outM[16], writeM, addressM[15], pc[15];

    PARTS:
    // 명령어 종류 판별
    Not(in=instruction[15], out=isA);
    And(a=instruction[15], b=true, out=isC);

    // A 레지스터 입력 선택
    Mux16(a=instruction, b=aluOut, sel=isC, out=aInput);
    And(a=isC, b=instruction[5], out=loadAFromC);
    Or(a=isA, b=loadAFromC, out=loadA);
    ARegister(in=aInput, load=loadA, out=aOut, out[0..14]=addressM);

    // D 레지스터
    And(a=isC, b=instruction[4], out=loadD);
    DRegister(in=aluOut, load=loadD, out=dOut);

    // ALU의 y 입력 선택: a-bit가 0이면 A, 1이면 M
    Mux16(a=aOut, b=inM, sel=instruction[12], out=aluY);

    ALU(x=dOut, y=aluY,
        zx=instruction[11],
        nx=instruction[10],
        zy=instruction[9],
        ny=instruction[8],
        f=instruction[7],
        no=instruction[6],
        out=aluOut,
        out=outM,
        zr=zr,
        ng=ng);

    // dest의 M 비트
    And(a=isC, b=instruction[3], out=writeM);

    // jump 계산
    Not(in=zr, out=notZr);
    Not(in=ng, out=notNg);
    And(a=notZr, b=notNg, out=positive);

    And(a=instruction[0], b=positive, out=jgt);
    And(a=instruction[1], b=zr, out=jeq);
    And(a=instruction[2], b=ng, out=jlt);

    Or(a=jgt, b=jeq, out=jump1);
    Or(a=jump1, b=jlt, out=jumpCond);
    And(a=isC, b=jumpCond, out=pcLoad);

    PC(in=aOut, load=pcLoad, inc=true, reset=reset, out[0..14]=pc);
}

// Computer
// 입력: reset
// 출력: 없음
// 동작:
// ROM32K에서 instruction을 읽고,
// CPU가 Memory를 읽고 쓰며,
// PC가 다음 명령어 주소를 결정함

CHIP Computer {
    IN reset;

    PARTS:
    ROM32K(address=pc, out=instruction);
    CPU(inM=memOut, instruction=instruction, reset=reset,
        outM=outM, writeM=writeM, addressM=addressM, pc=pc);
    Memory(in=outM, load=writeM, address=addressM, out=memOut);
}