Nand2Tetris — 第 2 章

//1位半加器
//輸入：a、b（1 位）
//輸出：和（a+b的LSB），進位（a+b的MSB）
//動作：sum = a XOR b，進位 = a AND b
CHIP HalfAdder {
    IN a, b;
    OUT sum,    // Right bit of a + b
        carry;  // Left bit of a + b

    PARTS:
    Xor(a=a, b=b, out=sum);
    And(a=a, b=b, out=carry);
}

//1位元全加器
//輸入：a、b、c（1位輸入+進位）
//輸出：和（a+b+c 的最低有效位元），進位（a+b+c 的最高有效位元）
//動作：先計算(a+b)，然後將c 加到結果中。
CHIP FullAdder {
    IN a, b, c;
    OUT sum,    // Right bit of a + b + c
        carry;  // Left bit of a + b + c

    PARTS:
    //第一個 HalfAdder：計算 a + b
    HalfAdder(a=a, b=b, sum=sum1, carry=carry1);

    //第二個 HalfAdder：計算 sum1 + c
    HalfAdder(a=sum1, b=c, sum=sum, carry=carry2);

    //最終進位：進位1或進位2
    Or(a=carry1, b=carry2, out=carry);
}

//16位元加法器（漣波進位方式）
//輸入：a[16]、b[16]（16 位數字，2 的補碼表示）
//輸出：out[16]（a + b的結果，忽略頂部進位）
//運算：第0位使用HalfAdder，第1~15位使用FullAdder。
CHIP Add16 {
    IN a[16], b[16];
    OUT out[16];

    PARTS:
    //位 0：無輸入進位
    HalfAdder(a=a[0], b=b[0],
              sum=out[0], carry=carry1);

    //Bits 1~15：接收上一步的進位輸入
    FullAdder(a=a[1], b=b[1], c=carry1,
              sum=out[1], carry=carry2);
    FullAdder(a=a[2], b=b[2], c=carry2,
              sum=out[2], carry=carry3);
    FullAdder(a=a[3], b=b[3], c=carry3,
              sum=out[3], carry=carry4);
    FullAdder(a=a[4], b=b[4], c=carry4,
              sum=out[4], carry=carry5);
    FullAdder(a=a[5], b=b[5], c=carry5,
              sum=out[5], carry=carry6);
    FullAdder(a=a[6], b=b[6], c=carry6,
              sum=out[6], carry=carry7);
    FullAdder(a=a[7], b=b[7], c=carry7,
              sum=out[7], carry=carry8);
    FullAdder(a=a[8], b=b[8], c=carry8,
              sum=out[8], carry=carry9);
    FullAdder(a=a[9], b=b[9], c=carry9,
              sum=out[9], carry=carry10);
    FullAdder(a=a[10], b=b[10], c=carry10,
              sum=out[10], carry=carry11);
    FullAdder(a=a[11], b=b[11], c=carry11,
              sum=out[11], carry=carry12);
    FullAdder(a=a[12], b=b[12], c=carry12,
              sum=out[12], carry=carry13);
    FullAdder(a=a[13], b=b[13], c=carry13,
              sum=out[13], carry=carry14);
    FullAdder(a=a[14], b=b[14], c=carry14,
              sum=out[14], carry=carry15);
    FullAdder(a=a[15], b=b[15], c=carry15,
              sum=out[15]);
}

//16位元增量器
//輸入：在[16]中
//輸出：in + 1 的結果
//操作：使用 Add16 新增 1
CHIP Inc16 {
    IN in[16];
    OUT out[16];

    PARTS:
    //in+1計算（1轉二進位：b[0]=1，餘數=0）
    Add16(a=in,
          b[0]=true,  b[1]=false, b[2]=false, b[3]=false,
          b[4]=false, b[5]=false, b[6]=false, b[7]=false,
          b[8]=false, b[9]=false, b[10]=false, b[11]=false,
          b[12]=false, b[13]=false, b[14]=false, b[15]=false,
          out=out);
}

//ALU（算術邏輯單元）
//輸入：x[16]、y[16]（16 位元輸入）
//zx、nx、zy、ny、f、no（控制訊號）
//輸出：out[16]（運算結果）
//zr（如果 out==0 則為 1，否則為 0）
//ng（如果 out<0，則為 1，否則為 0）
//
//動作流程：
//步驟1：如果zx=1，x=0，如果nx=1，x=NOT(x)
//步驟2：如果zy=1，y=0，如果ny=1，y=NOT(y)
//步驟3：如果f=1，則out=x+y（Add16），如果f=0，則out=x&y（And16）
//步驟 4：如果 no=1 則 out=NOT(out)
//步驟 5：計算 zr 和 ng 標誌
CHIP ALU {
    IN
        x[16], y[16],  // 16-bit inputs
        zx,             // zero x?
        nx,             // negate x?
        zy,             // zero y?
        ny,             // negate y?
        f,              // (x+y) or (x&y)?
        no;             // negate output?
    OUT
        out[16],        // 16-bit output
        zr,             // is out == 0?
        ng;             // is out < 0?

    PARTS:
    //第 1 步：x 預處理（零、求反）
    Mux16(a=x, b=false, sel=zx, out=xZero);
    Not16(in=xZero, out=xNot);
    Mux16(a=xZero, b=xNot, sel=nx, out=xProc);

    //步驟 2：預處理 y（零、求反）
    Mux16(a=y, b=false, sel=zy, out=yZero);
    Not16(in=yZero, out=yNot);
    Mux16(a=yZero, b=yNot, sel=ny, out=yProc);

    //步驟 3：選擇運算（ADD 或 AND）
    Add16(a=xProc, b=yProc, out=addRes);
    And16(a=xProc, b=yProc, out=andRes);
    Mux16(a=andRes, b=addRes, sel=f, out=fRes);

    //步驟4：輸出後處理（否定）+標誌
    Not16(in=fRes, out=fNot);
    Mux16(a=fRes, b=fNot, sel=no,
          out=out, out[15]=ng, out[0..7]=outLow, out[8..15]=outHigh);

    //第 5 步：計算 zr 標誌（所有位元進行“或”，然後“非”）
    Or8Way(in=outLow, out=orLow);
    Or8Way(in=outHigh, out=orHigh);
    Or(a=orLow, b=orHigh, out=orFinal);
    Not(in=orFinal, out=zr);
}